Nano-485/Software/TempSenderPlusIR/TempSenderPlusIR.ino

/*
 *  Demonstrates how to use Read Buttons in conjunction with SoftRS485:
 *
 * If a button is pressed, a corresponding flag is set.
 * The main loop checks for the state of those flags and
 * sends a message on the RS485 bus whenever a flag is set.
 * 
 * Additionally, the temperature is read from a DHT22 sensor once per minute
 */

// include the library code:
#include <SoftRS485.h>
#include <SimpleDHT.h>
#include <TinyIRSender.hpp>

// 0=Test
// 1=Flur
// 2=Wohnzimmer
// 3=Bad EG
// 4=Treppenhaus
// 5=Arbeitszimmer
// 6=Bad OG

#define ID 0
#define PROGRAM "Temp+IR"
#define SW_VERSION "0.1"
#define HW_VERSION "2.1"

#define BTN_INT 3 // button interrupt pin
#define Max485_RO 2 // read-output of Max485
#define Max485_RE 3 // not-read-enable of Max485
#define Max485_DE 8 // data enable of Max485
#define Max485_DI 9 // data input of Max485

#define TRESHOLD 1024
#define TRIGGER_LEVEL 200

#define DHT_PIN 4
#define PERIOD   100000000 // 100s

#define IR_PIN 5
#define REPEATS 2

//#define DEBUG
//#define LOG_TO_SERIAL
#define SEND_485

boolean raw_states[8];
boolean states[8];
unsigned long capacitor[8];
unsigned long times[8];
unsigned long sensor_time = 0;

// these values are used for temperature processing
SimpleDHT11 sensor(DHT_PIN);
byte temperature = 0;
byte humidity = 0;
int err = SimpleDHTErrSuccess;

// these constants are used for message parsing in handle(message)
const char* outer_delimiter = "{,}";
const char* inner_delimiter = ":";

void setup(){
  for (int i=0; i<8;i++) {
    capacitor[i] = 0;
    raw_states[i] = LOW;
    states[i] = LOW;
  }
  Serial.begin(115200);
  init485(Max485_RO,Max485_RE,Max485_DE,Max485_DI); // library initialization:
  pinMode(BTN_INT,INPUT_PULLUP);
  pinMode(14,INPUT_PULLUP);
  pinMode(15,INPUT_PULLUP);
  pinMode(16,INPUT_PULLUP);
  pinMode(17,INPUT_PULLUP);
  pinMode(18,INPUT_PULLUP);
  pinMode(19,INPUT_PULLUP);
  pinMode(20,INPUT_PULLUP);
  pinMode(21,INPUT_PULLUP);

  attachInterrupt(digitalPinToInterrupt(BTN_INT),isr,CHANGE);
  String s = "{nano:"+String(ID)+",hw:"+HW_VERSION+","+PROGRAM+":"+SW_VERSION+"}";
  Serial.println(s);
  send485(s.c_str());
#ifdef LOG_TO_SERIAL
  Serial.println("14 15 16 17 18 19 20 21");
#endif
}

void isr(){
  raw_states[0] = analogRead(14)<TRIGGER_LEVEL;
  raw_states[1] = analogRead(15)<TRIGGER_LEVEL;
  raw_states[2] = analogRead(16)<TRIGGER_LEVEL;
  raw_states[3] = analogRead(17)<TRIGGER_LEVEL;

  raw_states[4] = analogRead(18)<TRIGGER_LEVEL;
  raw_states[5] = analogRead(19)<TRIGGER_LEVEL;
  raw_states[6] = analogRead(20)<TRIGGER_LEVEL;
  raw_states[7] = analogRead(21)<TRIGGER_LEVEL;
#ifdef LOG_TO_SERIAL
  for (int i=0;i<8;i++){
    Serial.print(" ");    
    Serial.print(raw_states[i]);
    Serial.print(" ");
  }
  Serial.println();
#endif
}

void send(int btn, long duration){
  String s = "{nano:"+String(ID)+",btn:"+String(btn)+",ms:"+String(duration)+"}";
#ifdef SEND_485
  for (int i = 0; i<10; i++){
    if (send485(s.c_str())) break;
    Serial.println("collision detected, trying again:");
  }
#else
  Serial.println(s);
#endif
}




void handle(String message){
#ifdef LOG_TO_SERIAL
  Serial.println(message);
#endif   
  unsigned int ir_cmd = 0;
  unsigned int ir_addr = 0;
  unsigned int nano = 0;

  const char* outer_state = NULL;
  const char* inner_state = NULL;  
  char* token = strtok_r(message.c_str(), outer_delimiter, &outer_state);
  
  while (token != NULL) {    
    char* key = strtok_r(token,inner_delimiter,&inner_state);
    char* val = strtok_r(NULL,inner_delimiter,&inner_state);
    if (strcmp(key,"nano")==0) nano = atoi(val);      
    if (strcmp(key,"addr")==0) ir_addr = atoi(val);
    if (strcmp(key,"ir")==0) ir_cmd = atoi(val);
    token=strtok_r(NULL, outer_delimiter, &outer_state);
  }
  
  if (nano == ID){ // the message is addressed to us!
 
    if (ir_addr && ir_cmd){
#ifdef LOG_TO_SERIAL
      Serial.print("Sending 0x");
      Serial.print(ir_cmd,HEX);
      Serial.print(" to 0x");
      Serial.println(ir_addr,HEX);
#endif
      sendNECMinimal(IR_PIN, ir_addr, ir_cmd, REPEATS);
     }
  }
}

void loop(){
  unsigned long now = micros();
  for (int i=0;i<8;i++){
    // we emulate a capacitor:
    // when the button is pressed, it slowly loads, if the button is released, it unloads.
    capacitor[i] = raw_states[i] ? capacitor[i]+1 : capacitor[i]>>1;

    // if the capacitor reaches a certain treshold, the state is changed
    boolean new_state = capacitor[i]>TRESHOLD;

    // TODO: drop state after a maximum HIGH time

    // when the state changes, the duration of the last state is calculated
    if (states[i] != new_state){      
      long diff = (now - times[i])/1000;
      times[i] = now;
      if (states[i]) send(i+1,diff); // old state was HIGH → we are going LOW
      states[i] = new_state;
    }
  }

  if (now - sensor_time > PERIOD){
    sensor_time = now;
    if ((err = sensor.read(&temperature, &humidity, NULL)) == SimpleDHTErrSuccess) {
      String s = "{nano:"+String(ID)+",temp:"+String((int)temperature)+",humi:"+String((int)humidity)+"}";
#ifdef LOG_TO_SERIAL
      Serial.println(s);
#endif
      send485(s.c_str());
    }
  }
  
  if (available485()) handle(get485message());
}